home *** CD-ROM | disk | FTP | other *** search
/ Gold Medal Software 2 / Gold Medal Software Volume 2 (Gold Medal) (1994).iso / utils / bt108.arj / BT.ASM next >
Assembly Source File  |  1994-01-25  |  10KB  |  399 lines
  1.     page    ,132
  2.     title    BootThru  - v1.06
  3. ; For Borland:
  4. ;    tasm bt
  5. ;    tlink -t bt
  6. ;
  7. ;------------------------------------------------------------------------
  8. ;
  9. ;  BootThru  -    Copyright (c) Bill Gibson - 1987
  10. ;        Lathrup Village, Mi 48076
  11. ;
  12. ;  Ver. 1.00 - Initial version             (not rlsd) -  01/11/87
  13. ;    1.01 - revised code structure              "     -  01/25/87
  14. ;    1.02 - revised Modify Proc              "     -  02/01/87
  15. ;    1.03 - enhanced error message output          "     -  02/06/87
  16. ;    1.04 - revised Print Proc          released  -  02/07/87
  17. ;    1.05 - fix incompatibility plbm             -  02/09/87
  18. ;    1.06 - fix problem with DOS 3.2             -  05/31/87
  19. ;           DOS 3.2 believes the boot sector's information about
  20. ;           the disk in the drive.  v1.05 only worked with 360K disks.
  21. ;           v1.06 now reads the old boot sector and transfers the
  22. ;           information into the new boot sector.
  23. ;    1.07 - Took out waits
  24. ;        Fixed up boot header to be like DOS 4.0 & 5.0
  25. ;    1.08 - Minor changes
  26. ;
  27. ;
  28. ;  For Public Domain Use.  Not for Sale or Hire.
  29. ;  Last modified by:
  30. ;    Ray Van Tassle
  31. ;    1020 Fox Run Lane
  32. ;    Algonquin, Il   60102
  33. ;    (708) 658-4941
  34. ; 
  35.  
  36.  
  37. ;------------------------------------------------------------------------
  38. COMMENT *
  39.  
  40.       Routine to modify diskette boot record, using drive A: or B:,
  41.       thus circumventing DOS' non-system disk display error.
  42.  
  43.       Usage:
  44.             BT A:       -> transfer new boot record to drive A:
  45.             BT B:       -> transfer new boot record to drive B:
  46.             BT           -> starts program, default is drive A:
  47. *
  48. ;------------------------------------------------------------------------
  49. code        SEGMENT BYTE PUBLIC 'code'
  50. ASSUME        CS:code,DS:code,SS:code
  51.         ORG    5Ch            ;drive id
  52. param1        LABEL    BYTE
  53.         ORG    5Dh            ;elim spurrious characters
  54. param2        LABEL    BYTE
  55.  
  56.         ORG    100h
  57.  
  58. BootThru    PROC    FAR
  59.         CALL    Chk_Ver         ;dos 2.0 or greater
  60.  
  61.         CALL    Scan
  62.         CALL    Dwrite
  63.         JMP    SHORT exit
  64. error:
  65.         CALL    Print            ;print error messages
  66.         MOV    AL,1            ;set errorlevel to 1
  67. exit:
  68.         MOV    AH,4Ch
  69.         INT    21h
  70.  
  71. ;------------------------------------------------------------------------
  72. ; Work Area - constants,equates,messages
  73. ;------------------------------------------------------------------------
  74. drive        DB    0
  75.  
  76. blank        EQU    020h        ;ascii space code
  77. cr        EQU    0Dh        ;carriage return
  78. lf        EQU    0Ah        ;line feed
  79. ch_esc        EQU    01Bh        ;escape char
  80. stopper     EQU    255        ;end of display line indicator
  81.  
  82. logo    DB    cr,lf,'BootThru - The Diskette Modifier--boot thru floppy to the hard disk'
  83.     DB    cr,lf,'Version 1.08 - Bill Gibson & Ray Van Tassle',cr,lf,stopper
  84.  
  85. usage    DB    cr,lf,'Usage: BT [drive A: or B:]',cr,lf
  86.     db    '  Modifies floppy boot sector to boot from drive C:',stopper
  87. sorry    DB    cr,lf,'Wrong PC DOS Version',cr,lf,stopper
  88. msg1    DB    cr,lf,'Insert diskette in drive '
  89. drive_letter    DB    ?
  90.     db    stopper
  91.     DB    ' and press ENTER when ready ...',stopper
  92. msg3    DB    cr,lf,'Press ENTER to modify another disk',cr,lf
  93.     DB    'or ESCape to quit...',stopper
  94. msg4    DB    cr,lf,cr,lf,'Transferring New Boot Sector',cr,lf,stopper
  95. msg5    DB    cr,lf,'Transfer Completed',cr,lf,stopper
  96.  
  97. msg80h    DB    cr,lf,cr,lf,'* Error *  Drive failed to respond.',cr,lf,cr,lf,stopper
  98. msg40h    DB    cr,lf,cr,lf,'* Error *  Seek operation failed.',cr,lf,cr,lf,stopper
  99. msg20h    DB    cr,lf,cr,lf,'* Error *  Controller failure.',cr,lf,cr,lf,stopper
  100. msg10h    DB    cr,lf,cr,lf,'* Error *  Bad CRC on diskette write.',cr,lf,cr,lf,stopper
  101. msg08h    DB    cr,lf,cr,lf,'* Error *  DMA overrun on operation.',cr,lf,cr,lf,stopper
  102. msg04h    DB    cr,lf,cr,lf,'* Error *  Requested sector not found.',cr,lf,cr,lf,stopper
  103. msg03h    DB    cr,lf,cr,lf,'* Error *  Write protected diskette.',cr,lf,cr,lf,stopper
  104. msg02h    DB    cr,lf,cr,lf,'* Error *  Address mark not found.',cr,lf,cr,lf,stopper
  105. msggen    DB    cr,lf,cr,lf,'* Unknown Error *',cr,lf,cr,lf,stopper
  106.  
  107. ;--------------------------------------------------------------------------
  108. ; Sub-Routines:
  109. ;--------------------------------------------------------------------------
  110. Chk_Ver     PROC    NEAR
  111.         MOV    AH,30h        ;verify DOS 2.0 or later
  112.         INT    21h
  113.         CMP    AL,2
  114.         JAE    SHORT chk_ok
  115.         MOV    DX,OFFSET sorry
  116.         JMP    error
  117. chk_ok:
  118.         RET
  119. Chk_Ver     ENDP
  120.  
  121. ;--------------
  122.  
  123. Scan        PROC    NEAR        ;check for any spurrious chars
  124.         MOV    AL,[param2]
  125.         CMP    AL,blank        ;anything ?
  126.         JNZ    shlp            ;yes, give error msg
  127. s1:
  128.         MOV    AL,[param1]    ;check for drive parameters
  129.         OR    AL,AL            ;anything ?
  130.                 JZ      shlp                 ;no -
  131.         CMP    AL,01            ;setup for drive A:
  132.         JZ    SHORT sdrvOk
  133.         CMP    AL,02            ;for drive B:
  134.         JZ    SHORT sdrvOk
  135. shlp:
  136.         MOV    DX,OFFSET usage     ;display for invalid drives
  137.         JMP    error
  138. sdrvOk:
  139.         SUB    AL,1            ;remember the drive.
  140. sdrvDef:
  141.         MOV    drive,AL
  142.         ADD    AL,'A'
  143.         MOV    drive_letter,AL
  144.         MOV    DX,OFFSET logo
  145.         CALL    Print
  146.         MOV    DX,OFFSET msg1
  147.         RET
  148.  
  149. Scan        ENDP
  150.  
  151. ;--------------
  152.  
  153. Dwrite        PROC    NEAR        ;transfer new disk boot sector
  154.  
  155.         CALL    Print        ;get ready
  156. d1:    jmp d2
  157.         MOV    AH,8        ;use function 8 in order to detect
  158.         INT    21h        ;ctrl-breaks
  159.         CMP    AL,ch_esc    ;ESC & Ctrl-Break aborts process
  160.         JZ    d5
  161.         CMP    AL,cr
  162.         JNZ    d1
  163. d2:
  164.         MOV    DX,OFFSET msg4        ;setup for disk write
  165.         CALL    Print
  166.  
  167.         MOV    AL,drive        ;read the old boot sector.
  168.         LEA    BX,oldBoot
  169.         MOV    CX,0001
  170.         MOV    DX,0000
  171.  
  172.         PUSH    AX
  173.         PUSH    BX
  174.         PUSH    CX
  175.         PUSH    DX
  176.         INT    25h
  177.         JC    derror            ;processing error ?
  178.         POPF                ;done
  179.         POP    DX
  180.         POP    CX
  181.         POP    BX
  182.         POP    AX
  183.  
  184.         MOV    SI,OFFSET oldBoot+3+8    ;transfer the old bios parameters block.
  185.         MOV    DI,OFFSET head+3+8    ;into the new sector.
  186.         MOV    CX,OFFSET end_bpb
  187.         SUB    CX,DI
  188.         REP    MOVSB
  189.  
  190.         MOV    AL,drive
  191.         LEA    BX,head
  192.         MOV    CX,0001
  193.         MOV    DX,0000
  194.         PUSH    AX
  195.         PUSH    BX
  196.         PUSH    CX
  197.         PUSH    DX
  198.         INT    26h
  199.         JC    derror            ;processing error ?
  200.         POPF                ;done
  201.         POP    DX
  202.         POP    CX
  203.         POP    BX
  204.         POP    AX
  205. d3:
  206.         MOV    DX,OFFSET msg5        ;transfer complete
  207.         CALL    Print
  208.         JMP    d4
  209. derror:                     ;display disk errror
  210.         CALL    ErrorList
  211. dend_of:
  212.         CALL    Print
  213.         POPF                ;done
  214.         POP    DX
  215.         POP    CX
  216.         POP    BX
  217.         POP    AX
  218. d4:
  219.         jmp    d5
  220.         MOV    DX,OFFSET msg3        ;another ?
  221.         CALL    Print
  222.         JMP    d1            ;loop
  223. d5:
  224.         RET
  225. Dwrite        ENDP
  226.  
  227. ;--------------
  228.  
  229. Print        PROC    NEAR        ;a Great idea from Vern Buerg !
  230.         PUSH    SI
  231.         PUSH    BX
  232.         PUSH    CX
  233.         MOV    SI,DX        ;DX has the offset to string
  234.         SUB    CX,CX        ;set to zero for count
  235. p1:
  236.         LODSB
  237.         CMP    AL,stopper    ;string ends in FFh
  238.         JE    p9
  239.         INC    CX        ;increment text length
  240.         JMP    p1
  241. p9:
  242.         MOV    AH,40h        ;write using file handles
  243.         MOV    BX,1
  244.         INT    21h
  245.         POP    CX
  246.         POP    BX        ;recover registers
  247.         POP    SI
  248.         RET
  249. Print        ENDP
  250.  
  251. ;--------------
  252.  
  253. ErrorList    PROC    NEAR        ;error code interpretation
  254.                     ;the upper byte (AH) contains error
  255. err80h:     CMP    AH,080h         ;attachment failed to respond
  256.         JNZ    err40h
  257.         MOV    DX,OFFSET msg80h
  258.         RET
  259. err40h:
  260.         CMP    AH,040h         ;seek operation failed
  261.         JNZ    err20h
  262.         MOV    DX,OFFSET msg40h
  263.         RET
  264. err20h:
  265.         CMP    AH,020h         ;controller failed
  266.         JNZ    err10h
  267.         MOV    DX,OFFSET msg20h
  268.         RET
  269. err10h:
  270.         CMP    AH,010h         ;data error (bad CRC)
  271.         JNZ    err08h
  272.         MOV    DX,OFFSET msg10h
  273.         RET
  274. err08h:
  275.         CMP    AH,08h            ;direct memory access failure
  276.         JNZ    err04h
  277.         MOV    DX,OFFSET msg08h
  278.         RET
  279. err04h:
  280.         CMP    AH,04h            ;requested sector not found
  281.         JNZ    err03h
  282.         MOV    DX,OFFSET msg04h
  283.         RET
  284. err03h:
  285.         CMP    AH,03h            ;write-protect fault
  286.         JNZ    err02h
  287.         MOV    DX,OFFSET msg03h
  288.         RET
  289. err02h:
  290.         CMP    AH,02h            ;bad address mark
  291.         JNZ    errgen
  292.         MOV    DX,OFFSET msg02h
  293.         RET
  294. errgen:
  295.         MOV    DX,OFFSET msggen    ;something new ?  (Unknown)
  296.         RET
  297. ErrorList    ENDP
  298.  
  299. ;--------------
  300.  
  301. ;the new boot sector starts here.
  302. head:
  303. cr        EQU    0Dh        ;carriage return
  304. lf        EQU    0Ah        ;line feed
  305. stopper     EQU    255        ;end of display line indicator
  306. boot_area    EQU    0000h        ;setup boot area
  307. hard_drv    EQU    0080h        ;setup hard drive
  308. loc2        EQU    01FEh        ;last two bytes of boot sector
  309. eof_bootsec    EQU    0AA55h        ;end of boot sector (reversed)
  310. bulc        EQU    0DAh        ;box upper left corner
  311. burc        EQU    0BFh        ;box upper right corner
  312. bllc        EQU    0C0h        ;box lower left corner
  313. blrc        EQU    0D9h        ;box lower right corner
  314. bver        EQU    0B3h        ;vertical
  315. bhor        EQU    0C4h        ;horizontal
  316.  
  317.         JMP    startx        ;1st byte of the sector must be a jmp
  318.         DB    'BootThru'      ;8-byte system id
  319.         DW    512        ;sector size in bytes
  320.         DB    2        ;sectors per cluster
  321.         DW    1        ;reserved clusters
  322.         DB    2        ;number of fats
  323.         DW    112        ;root directory entries
  324.         DW    720        ;total sectors
  325.         DB    0FDh        ;format id  (2 sided, 9 sector)
  326.         DW    2        ;sectors per fat
  327.         DW    9        ;sectors per track
  328.         DW    2        ;sides
  329.         DW    0        ;special hidden sectors
  330. here:
  331. hdr_siz = 3+8+33h
  332. lz = hdr_siz - (here - head)
  333.         db lz dup(0)
  334. end_bpb:        ;;;;; This is the end of the DOS5.0 BPB
  335.  
  336.  
  337. startx:        jmp    start    ; Must jump to here, to be identical
  338. intro_beg:
  339.         DB   cr,lf
  340.         DB   cr,lf,bulc,46 DUP(bhor),burc
  341.         DB   cr,lf,bver,' This disk was modified by BootThru Ver 1.08  ',bver
  342.         DB   cr,lf,bver,'by Bill Gibson & Ray Van Tassle     Booting C:',bver
  343.         DB   cr,lf,bllc,46 DUP(bhor),blrc
  344.         DB   cr,lf,stopper
  345.  
  346. intro_offset    EQU    intro_beg - head
  347.  
  348. start:        MOV    AX,07C0h    ;boot record location
  349.         MOV    ES,AX
  350.         MOV    DS,AX
  351.         MOV    SI,intro_offset
  352.         CLD            ;just in case.
  353. strt1:        MOV    AH,0Eh        ;write teletype
  354.         LODSB
  355.         CMP    AL,stopper
  356.         JE    SHORT strt2
  357.  
  358.         PUSH    SI
  359.         INT    10h
  360.         POP    SI
  361.         JMP    SHORT strt1
  362.  
  363. strt2:        CLD            ;move the boot sector up.
  364.         MOV    SI,0
  365.         MOV    DI,0200h    ;boot sector size
  366.         MOV    CX,0200h
  367.         REPZ  MOVSB
  368.         JMP    strt3 + 200h    ;jump to the new copy of it.
  369.  
  370. strt3:        MOV    AH,2        ;function 02h - read disk.
  371.         MOV    BX,boot_area    ;boot area
  372.         MOV    CH,0        ;track number
  373.         MOV    CL,1        ;sector
  374.         MOV    DH,0        ;head
  375.         MOV    DL,hard_drv    ;hard drive
  376.         MOV    AL,1        ;number of sectors
  377.         INT    13h
  378. ;setup to pull ROM Basic in if the hard drive has no boot sector.
  379. strt4:        CMP    word ptr DS:loc2,eof_bootsec
  380.         JNZ    strt9
  381.         JMP    head - 200h    ;jump to the new boot sector.
  382.  
  383. strt9:        INT    18h
  384.  
  385.         DB    'BootThru, Copyright (c) Bill Gibson'
  386. tail:
  387. filler_amount    EQU    512 - (tail - head) - 2
  388.  
  389.         DB    filler_amount dup (0)
  390. boot_id     DW    eof_bootsec
  391.  
  392.  
  393. BootThru    ENDP
  394.  
  395. oldBoot        label    byte
  396.  
  397. code        ENDS
  398.         END    BootThru
  399.